Podgląd numeru seryjnego systemu operacyjnego Windows 10, 8, 7

Jeżeli zapomniałeś lub zgubiłeś klucz systemu operacyjnego Windows 10, Windows 8 lub Windows 7, możesz go wyświetlić na swoim komputerze używając prostego skryptu VBS. Nowe komputery z zainstalowanym systemem Windows 10 nie posiadają naklejki licencyjnej z numerem seryjnym systemu – na przykład laptopy Lenovo serii Y700.

Aby wyświetlić numer licencji systemu operacyjnego przy użyciu skryptu VBS wykonujemy poniższe czynności:

1. Otwieramy Notatnik.
2. Wklejamy poniższy kod do Notatnika :

Option Explicit 

Dim objshell,path,DigitalID, Result 
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID) 
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file 
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData 
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
       	Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0 
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
    
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name 
    UserName = objshell.ExpandEnvironmentStrings("%UserName%") 
    'Create a text file on desktop 
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function

3. Zapisujemy plik jako „Windows-Key.vbs”, pamiętajmy o rozszerzeniu VBS.
4. Uruchamiamy zapisany plik Windows-Key.vbs.
5. Po uruchomieniu pliku wyświetla nam się okno z numerem licencji, jak na poniższym zdjęciu.

Wyświetlenie numeru licencji

Wyświetlenie numeru licencji

6. Jeśli klikniemy przycisk TAK w wyświetlonym oknie, dodatkowo mamy możliwość zapisu informacji o licencji do pliku tekstowego.

Jak widzimy jest to bardzo szybki sposób na wyświetlenie naszego klucza licencji, skrypt działa poprawnie w systemie Windows 10, Windows 8 oraz Windows 7, w przypadku wersji systemu korporacyjnego „Enterprise” nasz numer seryjny nie zostanie wyświetlony, ale do domowych zastosowań nadaje się idealnie. Gotowy do użytku skrypt możecie pobrać z linku poniżej.

Źródło : winaero.com

Pliki do artykułu :  Windows key